Hiện đang hiểu là, chương trình cứ loop mỗi lần 1s, sau mỗi 1s sẽ kiểm tra kí tự nhập và in ra số kí tự nhập. Nếu có interrupt từ bàn phím (lúc này là ENTER nhưng chưa biết locate ở đâu) => sẽ nhảy vào interrupt. Trong interrupt sẽ hiển thị ra những kí tự nhập vào trên MMIO, và in ra số kí tự đúng, cũng như cho phép người dùng lặp lại chương trình hay k

**Bài 3: Kiểm tra tốc độ và độ chính xác khi gõ văn bản**

Sinh viên xử lí bài tập: **Phạm Lê Đức – 20161128**

**Đề bài**: Chương trình sau sẽ đo tốc độ gõ bàn phím và hiển thị kết quả bằng 2 đèn led 7 đoạn. Nguyên tắc:

- Cho một đoạn văn bản mẫu, cố định sẵn trong mã nguồn. Ví dụ “bo mon ky thuat may tinh” - Sử dụng bộ định thời Timer (trong bộ giả lập Digi Lab Sim) để tạo ra khoảng thời gian để đo. Đây là thời gian giữa 2 lần ngắt, chu kì ngắt.

- Trong thời khoảng đó, người dùng nhập các kí tự từ bàn phím. Ví dụ nhập “bo mOn ky 5huat may tinh”. Chương trình cần phải đếm số kí tự đúng (trong ví dụ trên thì người dùng gõ sai chữ O và 5) mà người dùng đã gõ và hiển thị lên các đèn led.

**Source code**:

.eqv SEVENSEG\_LEFT 0xFFFF0011 # LED LEFT

.eqv SEVENSEG\_RIGHT 0xFFFF0010 # LED RIGHT

.eqv KEY\_CODE 0xFFFF0004 # ASCII code from keyboard, 1 byte

.eqv KEY\_READY 0xFFFF0000 # =1 if has a new keycode

# Auto clear after lw

.eqv DISPLAY\_CODE 0xFFFF000C # ASCII code to show, 1 byte

.eqv DISPLAY\_READY 0xFFFF0008 # =1 if the display has already to do

# Auto clear after sw

.eqv MASK\_CAUSE\_KEYBOARD 0x0000034 # Keyboard Cause

.data

bytehex : .byte 63,6,91,79,102,109,125,7,127,111 # this is the decimal representation of numbers from 0 to 9 for 7 segments. 63 is 0 and 111 is 9

storestring : .space 1000 # maximum 25 words to store in this array

stringsource : .asciiz "Bo mon ky thuat may tinh"

numkeyright: .asciiz "\n The number of matched characters: "

notification: .asciiz "\n Continue using or quit? "

testing: .asciiz "\n length of the typed string: "

string: .asciiz "\n String: "

startmain: .asciiz "\n Start main. "

startReadingKey: .asciiz "\n Start reading key. "

array: .word 10000

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

# MAIN Procsciiz ciiz edure

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

.text

li $k0, KEY\_CODE

li $k1, KEY\_READY

li $s0, DISPLAY\_CODE

li $s1, DISPLAY\_READY

MAIN:

li $s4,0 # length cua storestring later on

li $t9,10

li $v0, 4

la $a0, startmain

syscall

nop

li $s6, 0 # flag var to turn on / off ask loop

li $t3, 0 # the number of matched characters

li $s7, 0 # count time

LOOP:

nop

WAIT\_FOR\_KEY:

lb $t5, 0($k1) # check if a key is pressed or not

beq $t5, $zero, CHECK # if no key then we check condition

nop

READ\_KEY:

lb $t0, 0($k0) # $t0 = [$k0] = KEY\_CODE. Here we use lb for efficient data storage because ASCII only goes to 127 max, which is 8 bits

#WAIT\_FOR\_DIS:

# lb $t2, 0($s1) # $t2 = [$s1] = DISPLAY\_READY. $s1 only has two values 0 or 1

# beq $t2, $zero, WAIT\_FOR\_DIS # if $t2 == 0 then Polling

# nop

SHOW\_KEY:

sb $t0, 0($s0) # show the input key when key ready has a signal 1 on MMIO

la $s5,storestring # the address of our input string is stored in $s5

add $s5,$s5,$s4

sb $t0,0($s5) # store the input key into the string

addi $s4,$s4,1 # i = i + 1 so

nop

CHECK:

addi $s7, $s7, 1 # increase time by one

teqi $s7, 500 # if finish 500ms get into interrupt

SLEEP:

addi $v0,$zero,32 # sleep service, just to get back to loop, used to avoid some unpexpected bugs

li $a0, 5 # $a0 = sleep length, which is 5ms in this case

syscall

nop # WARNING: nop is mandatory here.

#li $s4, 0 # reset count

j LOOP # Loop

j LOOP

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

# PHAN PHUC VU NGAT

#~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~

.ktext 0x80000180 #chuong trinh con chay sau khi interupt duoc goi.

IntSR: #--------------------------------------------------------

# Temporary disable interrupt

#--------------------------------------------------------

dis\_int:

mfc0 $t1, $13 # the cause of interrupt is stored inside $t1

KEYBOARD:

li $t2, MASK\_CAUSE\_KEYBOARD

and $at, $t1, $t2

beq $at, $t2, END

nop

j END\_PROCESS

END: #PRINTING

li $v0,11

li $a0,'\n' # new line

syscall

li $v0, 4

la $a0, testing

syscall

li $v0, 1

add $a0, $s4, $zero

syscall

li $v0, 4

la $a0, string

syscall

li $v0, 4

la $a0, storestring

syscall

li $v0,11

li $a0,'\n' # new line

syscall

nop

li $t1,0 #dem so ky tu da duoc xet

li $t3,0 # dem so ky tu nhap dung

li $t8,24 #luu $t8 la do dai xau da luu tru trong ma nguon.

beq $s4, 0, PRINT

nop

slt $t7,$s4,$t8 #so sanh xem do dai xau nhap tu ban phim va do dai cua xau co dinh trong ma nguon

#xau nao nho hon thi duyet theo do dai cua xau do

bne $t7,1, CHECK\_STRING

nop

add $t8,$0,$s4

CHECK\_STRING: # when the original string has a greater length

la $t2,storestring # handle the typed string

add $t2,$t2,$t1

lb $t5,0($t2) #lay ky tu thu $t1 trong storestring luu vao $t5 de so sanh voi ky tu thu $t1 o stringsource

la $t4,stringsource # handle the source string

add $t4,$t4,$t1

lb $t6,0($t4) #lay ky tu thu $t1 trong stringsource luu vao $t6

bne $t6, $t5, CONTINUE # if they are not similar then we skip increment of corrected characters

nop

addi $t3,$t3,1 # if it is similar then we increase the counting register by one

CONTINUE:

addi $t1,$t1,1 # increase i to continue looping

beq $t1,$t8,PRINT # if i reach the length of the string we are looping then we stop

nop

j CHECK\_STRING #con khong thi tiep tuc xet tiep cac ky tu

PRINT: li $v0,4

la $a0,numkeyright

syscall

li $v0,1

li $a0, 0

add $a0, $a0, $t3

syscall

DISPLAY\_DIGITAL:

li $t9, 10 # set t9 to 10 for certainty that it is 10 to divide

div $t3,$t9 #lay so ky tu nhap duoc trong 1s chia cho 10 - this needs to be fixed because if the total letters are more than 100 then it will be wrong

mflo $t8 #luu gia tri phan nguyen, gia tri nay se duoc luu o den LED ben trai

la $s2,bytehex # store the address of the array containing the values of 7 segment numbers

add $s2,$s2,$t8 #xac dinh dia chi cua gia tri

lb $a0,0($s2) #lay noi dung cho vao $a0

jal SHOW\_7SEG\_LEFT # ngay den label den LED trai

#------------------------------------------------------------------------

mfhi $t7 #luu gia tri phan du cua phep chia, gia tri nay se duoc in ra trong den LED ben phai

la $s2,bytehex

add $s2,$s2,$t7

lb $a0,0($s2) # set value for segments

jal SHOW\_7SEG\_RIGHT # show

#------------------------------------------------------------------------

li $s6, 1 # turn on ask loop

beq $s4, 0, END\_PROCESS

li $t3, 0

nop

SMALL\_LOOP:

li $s6, 0 # used as a value to clean buffer

la $s5, storestring

add $s5, $s5, $t3

sb $s6, 0($s5) # set the whole string to 0

add $t3, $t3, 1 # increase index

bne $t3, $s4, SMALL\_LOOP # finish when i = n

nop

li $s6, 1

j END\_PROCESS

nop

SHOW\_7SEG\_LEFT:

li $t0, SEVENSEG\_LEFT # assign port's address

sb $a0, 0($t0) # assign new value

jr $ra

SHOW\_7SEG\_RIGHT:

li $t0, SEVENSEG\_RIGHT # assign port's address

sb $a0, 0($t0) # assign new value

jr $ra

END\_PROCESS: .

mtc0 $zero, $13 # need to clear the cause of interrupt here ($13 = 0)

beq $s6, 1, ASK\_LOOP

nop

# Evaluate the return address of main routine

# epc <= epc + 4

#--------------------------------------------------------

NEXT\_PC:

mfc0 $at, $14 # $at <= Coproc0.$14 = Coproc0.epc

addi $at, $at, 4 # $at = $at + 4 (next instruction)

mtc0 $at, $14 # Coproc0.$14 = Coproc0.epc <= $at

nop

RETURN:

eret # tro ve len ke tiep cua chuong trinh chinh

nop

ASK\_LOOP:

li $v0, 50

la $a0, notification

syscall

beq $a0,0,RESET\_DATA

nop

b EXIT

RESET\_DATA:

li $t3, 0 # reset corrected counter register

li $v0, 32 # change back to sleep service due to strange bug

li $s4, 0 # reset index

li $s6, 0 # reset ask loop

li $s7, 0 # reset

j NEXT\_PC

EXIT:

li $v0, 10

syscall

Phân tích: Để làm được bài này, thì cần ba giai đoạn lớn:

* Giai đoạn 1: Thiết lập dữ liệu cần thiết cho chương trình. Cụ thể, ta cần setup những symbols như SEVENSEG\_LEFT, SEVENSEG\_RIGHT, DISPLAY\_CODE cũng như 1 vài symbols nữa để sử dụng cho Digital Lab cũng như MMIO. Như đã biết SEVENSEG\_LEFT lưu địa chỉ của LED bên trái, và khi ta set giá trị tại địa chỉ này => sẽ hiện lên Digital lab. Bởi vì ta không biết ta cần numbers gì, vậy nên các số từ 0 -> 9 sẽ được lưu vào 1 array.

Ngoài ra, ta cũng cần sử dụng 1 số registers để làm các variables increment cho loop, cũng như 2 registers để chứa length của source string, và typed string.

* Giai đoạn 2: Lắng nghe input keyboard từ người dùng đồng thời đếm thời gian tạo ngắt (interrupt)

Bởi vì Time Counter của MARS có nhiều bugs, ngoài ra việc chạy đồng thời sleep service cho Time Counter (bắt buộc bởi vì nó là bugs, không kiểm soát được) và phải chạy vòng lặp liên tục để lấy input của users là rất khó. Vậy em xin phép được sử dụng 1 phương pháp tương tự, cơ chế chạy hoàn toàn giống nhau, vẫn đếm thời gian nhưng không sử dụng công cụ Time Counter của Digital Lab.

Đầu tiên ta sẽ check tín hiệu input của người dùng ($k1, KEY\_READY), nếu nó bằng 0 tức không có input truyền vào, thì ta jump đến vị trí sử dụng biến đếm thời gian. Ở đây ta coi thời gian như những vòng lặp với giới hạn là số lần lặp của nó. Ở đây interval của nó là 500 lần lặp – 1 khoảng tgian vừa đủ để nhập 1 đoạn string không quá ngắn cũng không quá dài. Vậy khi nhảy đến vị trí sử dụng biến đếm, ta increment biến đếm lên 1 và check, nếu như đã reach 500 thì ta sử dụng ngắt mềm thông qua lệnh teqi để nhảy vào interrupt.

Nếu như bằng 1 thì tức là có input, lúc này ta sẽ đọc input key, sau đó ta show lên MMIO, đồng thời lưu nó vào trong 1 ô của variable string ta đã setup từ đầu. Lưu ý, chỗ này ta sử dụng byte hay lb sb thay vì lw sw. Lý do bởi vì ASCII table chỉ tới 8 bits mà max, ngoài ra ta cần lưu từng character, vậy nên data string của ta phải là .space và dùng hoàn toàn với 1 byte thay vì 4 bytes (1 word). Sau khi lưu, ta tăng biến đếm length của string lên 1 và tiếp tục loop để kiểm tra kí tự đầu vào tiếp theo.

* Giai đoạn 3: xử lí interrupt

Khi đã vào interrupt, ta sẽ check xem có đúng là interrupt do ta vừa call từ trên không (thông qua mfc0 $t1, $13). Con processor 13 sẽ lưu cause, và truyền nó vào trong $t1. Sau đó ta kiểm tra xem cause này có khớp với cause ta muốn (đó chính là MASK\_CAUSE\_KEYBOARD lưu ở 0x0000034).

Nếu đúng thì ta sẽ in 1 số dòng output nhất định cho người dùng (string đã nhập, số kí tự đã nhập). Nếu sai thì sẽ nhảy tới END\_PROCESS luôn và tiếp tục đọc lại.

Sau khi in xong, ta kiểm tra sự giống nhau của 2 strings theo thuật toán sau đây (viết bằng ngôn ngữ C. Thuật toán sẽ không khớp với trình bày ở source code 100%, nhưng ý tưởng và cách thức thực hiện tương đồng):

srcString = lengthString (lengthString đã được fixed từ trước);

desString = countedLength(countedLength đã được incremented ở giai đoạn 2)

int checkString(char \*srcString, char\* desString) {

If (desString == 0) // nếu không nhập gì)

Return -1; // không thực sự return gì ở source code, mà nhảy tới lúc in kết quả luôn

Else {

Int total = 0; // biến lưu tổng những kí tự đúng

Int length = 0;

If (srcString < desString) // ý tưởng là xét length nhỏ hơn.

Length = srcString;

else

Length = desString;

// loop qua 2 string để check sự tương đồng

For (int I = 0; I < length; i++) {

If (srcString[i] == desString[i])

Total = total + 1;

}

}

Return total;

}

Sau khi thu được số lượng characters khớp, ta in ra và sử dụng nó để hiển thị lên Digital Lab.

Cách thức hiển thị: Vì giới hạn Digital Lab chỉ có 2 LED, vậy nên thuật toán này cũng chỉ đúng trong phạm vi từ 0 -> 99, nếu số characters >= 100 sẽ sai. Thuật toán sử dụng biến total / 10, phần nguyên sẽ là phần hiển thị lên đèn LED bên trái, và phần dư sẽ được hiển thị lên đèn LED bên phải (sử dụng mflo và mfhi sau khi chia). Sau đó, ta sử dụng 1 array gồm các số từ 0 đến 9 (lưu dưới dạng bytes or giống với ASCII, chuyển từ binary ra decimal sẽ thu được). Lấy địa chỉ của array này (la $s2,bytehex) sau đó cộng address với phần nguyên (cho LED trái) và phần dư (cho LED phải) để thu được chính xác số mà ta mong muốn. Lý do cộng được bởi vì như giải thích ở trên – array này được lưu dưới dạng byte thay vì word, vậy khi increment từng ô thì ta +1 thay vì +4.

Sau khi hiển thị xong, ta clean buffer (input string) bằng cách loop qua nó và set từng ô kí tự bằng 0. Rồi dùng popup service để hỏi người dùng xem có muốn tiếp tục không. Nếu tiếp tục thì sẽ retrieve instruction được lưu ở Coproc $14 khi interrupt xảy ra. Để tiếp đến instruction tiếp theo thì ta increment lên 4 (addi $at, $at, 4), và sau đó lại truyền giá trị vào $14, và gọi eret (giống như $ra) để nhảy tới địa chỉ ta vừa set – next instruction.

Sau khi quay trở về, ta lại có 1 vòng lặp mới và chương trình cứ thế tiếp diễn. Nếu không tiếp tục thì chương trình sẽ kết thúc.

Ảnh output: 